Motor.h

Go to the documentation of this file.

#pragma once

class Motor{
  public:
    const byte FULL_OFF = 255; 
    const byte FULL_ON =  0; 
    double percentage = 0; 
     Motor (byte direction, byte pwm, byte tachPin) {
        directionPin = direction;
        pwmPin = pwm;
        tachometerPin = tachPin;

        minUsablePercent = 40;
        maxUsablePercent = 100;
        /*
         * Change the prescaler for timer 1 (used by the motor PWM) to increase the PWM frequency
         * to 31250Hz so that it can not be heard  (1=31250Hz, 2=3906Hz, 3=488Hz, 4=122Hz, 5=30.5Hz)
         */
        TCCR1B = (TCCR1B & B11111000) | 1;
        setupMotor();
      }

    void setupMotor() {
      pinMode(directionPin, OUTPUT);
      pinMode(pwmPin, OUTPUT);
      analogWrite(pwmPin, FULL_OFF); //Write off to ensure motor is initialized to be off

      pinMode(tachometerPin, INPUT_PULLUP);
    }

     void runMotor(double percent){
      if(percent < 0){
        digitalWrite(directionPin, LOW);
      }
      else{
        digitalWrite(directionPin, HIGH);
      }

      analogWrite(pwmPin, turnPercentIntoPwm(percent));
      percentage = percent;
    }

   double turnPercentIntoPwm(double percent){
    // Maps the input percentage (0-100%) into a usable percentage for the motor based off minUsablePercent and maxUsablePercent
    if (percent > 0) {
      percent = map(percent, 0, 100, minUsablePercent, maxUsablePercent);
    } else if (percent < 0) {
      percent = map(percent, 0, -100, minUsablePercent, maxUsablePercent);
    }
    
    return 255 - (255 * abs(percent) / 100);
   }

    void turnOffMotor() {
      analogWrite(pwmPin, FULL_OFF);
    }

    void turnOnMotor() {
      analogWrite(pwmPin, FULL_ON);
    }

    void increasePercentage(double step){
      if(percentage < 100){
        percentage += step;
        runMotor(percentage);
      }
    }

    void decreasePercentage(double step){
      if(percentage > -100){
        percentage -= step;
        runMotor(percentage);
      }
    }
    void interruptServiceRoutine() {
      newTime = micros();
      microsecondsBetweenLines = newTime - timeOfLastMeasurement;
      timeOfLastMeasurement = newTime;
      rotationsPerMinute = 24000000 / microsecondsBetweenLines;
    }

    unsigned long getRotationsPerMinute(){
      return rotationsPerMinute;
    }

    byte getTachAttachedPin(){
      return tachometerPin;
    }

    double getPercentage(){
      return percentage;
    }
    
    double getDirection(){
      return digitalRead(directionPin); 
    }

    bool setMinimumUsablePercent(byte percent){
        if((percent < 0) || (percent > 100)){ //Ignore this request
          return false;
        }

        minUsablePercent = percent;
        return true;
    }

    byte getMinUsablePercent(){
      return minUsablePercent;
    }

    byte getMaxUsablePercent(){
      return maxUsablePercent;
    }

    bool setMaxUsablePercent(byte percent){
      if((percent < minUsablePercent)){ // If the percent is less than minUsablePercent return
        return false;
      }else if((percent < 0) || (percent > 100)){ // If the percent is negative or greater than 100
        return false;
      }

      maxUsablePercent = percent;
      return true;
    }

  private:
    byte minUsablePercent; 
    byte  maxUsablePercent; 
    byte pwmPin, directionPin, tachometerPin;
    unsigned long rotationsPerMinute, newTime, timeOfLastMeasurement, microsecondsBetweenLines;
};